      SUBROUTINE DTBSV ( UPLO, TRANS, DIAG, N, K, A, LDA, X, INCX )
****************************************************************************
*                                                                          *
*   DATA PARALLEL BLAS based on MPL                                        *
*                                                                          *
*   Version 1.0   1/9-92 ,                                                 *
*   For MasPar MP-1 computers                                              *
*                                                                          *
*   para//ab, University of Bergen, NORWAY                                 *
*                                                                          *
*   These programs must be called using F90 style array syntax.            *
*   Note that the F77 style calling sequence has been retained             *
*   in this version for compatibility reasons, be aware that               *
*   parameters related to the array dimensions and shape therefore may     *
*   be redundant and without any influence.                                *
*   The calling sequence may be changed in a future version.               *
*   Please report any BUGs, ideas for improvement or other                 *
*   comments to                                                            *
*                    adm@parallab.uib.no                                   *
*                                                                          *
*   Future versions may then reflect your suggestions.                     *
*   The most current version of this software is available                 *
*   from netlib@nac.no , send the message `send index from maspar'         *
*                                                                          *
*   REVISIONS:                                                             *
*                                                                          *
****************************************************************************
      implicit none
*     .. Scalar Arguments ..
      INTEGER            INCX, K, LDA, N
      CHARACTER*1        DIAG, TRANS, UPLO
*     .. Array Arguments ..
      double precision, array(:,:) :: a
      double precision, array(:) :: x
      intent(inout) :: a, x
*     ..
*
*  Purpose
*  =======
*
*  DTBSV  solves one of the systems of equations
*
*     A*x = b,   or   A'*x = b,
*
*  where b and x are n element vectors and A is an n by n unit, or
*  non-unit, upper or lower triangular band matrix, with ( k + 1 )
*  diagonals.
*
*  No test for singularity or near-singularity is included in this
*  routine. Such tests must be performed before calling this routine.
*
*  Parameters
*  ==========
*
*  UPLO   - CHARACTER*1.
*           On entry, UPLO specifies whether the matrix is an upper or
*           lower triangular matrix as follows:
*
*              UPLO = 'U' or 'u'   A is an upper triangular matrix.
*
*              UPLO = 'L' or 'l'   A is a lower triangular matrix.
*
*           Unchanged on exit.
*
*  TRANS  - CHARACTER*1.
*           On entry, TRANS specifies the equations to be solved as
*           follows:
*
*              TRANS = 'N' or 'n'   A*x = b.
*
*              TRANS = 'T' or 't'   A'*x = b.
*
*              TRANS = 'C' or 'c'   A'*x = b.
*
*           Unchanged on exit.
*
*  DIAG   - CHARACTER*1.
*           On entry, DIAG specifies whether or not A is unit
*           triangular as follows:
*
*              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
*
*              DIAG = 'N' or 'n'   A is not assumed to be unit
*                                  triangular.
*
*           Unchanged on exit.
*
*  N      - INTEGER.
*           On entry, N specifies the order of the matrix A.
*           N must be at least zero.
*           Unchanged on exit.
*
*  K      - INTEGER.
*           On entry with UPLO = 'U' or 'u', K specifies the number of
*           super-diagonals of the matrix A.
*           On entry with UPLO = 'L' or 'l', K specifies the number of
*           sub-diagonals of the matrix A.
*           K must satisfy  0 .le. K.
*           Unchanged on exit.
*
*  A      - DOUBLE PRECISION array of DIMENSION ( LDA, n ).
*           Before entry with UPLO = 'U' or 'u', the leading ( k + 1 )
*           by n part of the array A must contain the upper triangular
*           band part of the matrix of coefficients, supplied column by
*           column, with the leading diagonal of the matrix in row
*           ( k + 1 ) of the array, the first super-diagonal starting at
*           position 2 in row k, and so on. The top left k by k triangle
*           of the array A is not referenced.
*           The following program segment will transfer an upper
*           triangular band matrix from conventional full matrix storage
*           to band storage:
*
*                 DO 20, J = 1, N
*                    M = K + 1 - J
*                    DO 10, I = MAX( 1, J - K ), J
*                       A( M + I, J ) = matrix( I, J )
*              10    CONTINUE
*              20 CONTINUE
*
*           Before entry with UPLO = 'L' or 'l', the leading ( k + 1 )
*           by n part of the array A must contain the lower triangular
*           band part of the matrix of coefficients, supplied column by
*           column, with the leading diagonal of the matrix in row 1 of
*           the array, the first sub-diagonal starting at position 1 in
*           row 2, and so on. The bottom right k by k triangle of the
*           array A is not referenced.
*           The following program segment will transfer a lower
*           triangular band matrix from conventional full matrix storage
*           to band storage:
*
*                 DO 20, J = 1, N
*                    M = 1 - J
*                    DO 10, I = J, MIN( N, J + K )
*                       A( M + I, J ) = matrix( I, J )
*              10    CONTINUE
*              20 CONTINUE
*
*           Note that when DIAG = 'U' or 'u' the elements of the array A
*           corresponding to the diagonal elements of the matrix are not
*           referenced, but are assumed to be unity.
*           Unchanged on exit.
*
*  LDA    - INTEGER.
*           On entry, LDA specifies the first dimension of A as declared
*           in the calling (sub) program. LDA must be at least
*           ( k + 1 ).
*           Unchanged on exit.
*
*  X      - DOUBLE PRECISION array of dimension at least
*           ( 1 + ( n - 1 )*abs( INCX ) ).
*           Before entry, the incremented array X must contain the n
*           element right-hand side vector b. On exit, X is overwritten
*           with the solution vector x.
*
*  INCX   - INTEGER.
*           On entry, INCX specifies the increment for the elements of
*           X. INCX must not be zero.
*           Unchanged on exit.
*
*
*  Level 2 Blas routine.
*
*  -- Written on 22-October-1986.
*     Jack Dongarra, Argonne National Lab.
*     Jeremy Du Croz, Nag Central Office.
*     Sven Hammarling, Nag Central Office.
*     Richard Hanson, Sandia National Labs.
*
*
*     .. Local Scalars ..
      DOUBLE PRECISION   TEMP
      INTEGER            I, INFO, IX, J, JX, KPLUS1, KX, L
      LOGICAL            NOUNIT, UPPER
*     .. Local Arrays ..
      double precision, array(N) :: xloc
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           LSAME
*     .. External Subroutines ..
      EXTERNAL           XERBLA
*     .. Intrinsic Functions ..
      INTRINSIC          MAX, MIN
      INTRINSIC          cshift
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      NOUNIT = LSAME( DIAG, 'N' )
      UPPER  = LSAME( UPLO, 'U' )
*
      INFO = 0
      IF     ( .NOT.UPPER              .AND.
     $         .NOT.LSAME( UPLO , 'L' )      )THEN
         INFO = 1
      ELSE IF( .NOT.LSAME( TRANS, 'N' ).AND.
     $         .NOT.LSAME( TRANS, 'T' ).AND.
     $         .NOT.LSAME( TRANS, 'C' )      )THEN
         INFO = 2
      ELSE IF( .NOT.LSAME( DIAG , 'U' ).AND.
     $         .NOT.LSAME( DIAG , 'N' )      )THEN
         INFO = 3
      ELSE IF( N.LT.0 )THEN
         INFO = 4
      ELSE IF( K.LT.0 )THEN
         INFO = 5
      ELSE IF( LDA.LT.( K + 1 ) )THEN
         INFO = 7
      ELSE IF( INCX.EQ.0 )THEN
         INFO = 9
      END IF
      IF( INFO.NE.0 )THEN
         CALL XERBLA( 'DTBSV ', INFO )
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( N.EQ.0 ) RETURN
*
*     Set up the start point in X if the increment is not unity. This
*     will be  ( N - 1 )*INCX  too small for descending loops.
*
      IF( INCX.LE.0 )THEN
         KX = 1 - ( N - 1 )*INCX
      ELSE IF( INCX.NE.1 )THEN
         KX = 1
      END IF
*
      if( incx.eq.1 )then
         xloc(1:n) = x(1:n)
      else
         xloc(1:n) = x(kx : kx+incx*(n-1) : incx)
      end if
*
*     Start the operations. In this version the elements of A are
*     accessed by sequentially with one pass through A.
*
      KPLUS1 = K + 1
      IF( LSAME(TRANS, 'N') )THEN
*
*        Form  x := inv( A )*x.
*
         IF( UPPER )THEN
            IF( NOUNIT ) then
               DO J = N, 2, -1
               xloc(J) = xloc(J) / A(KPLUS1,J)
               l = max( 1, J - K )
               xloc(l:j-1)=xloc(l:j-1)-xloc(j)*A(kplus1-j+l:k,j)
	       ENDDO
               xloc(1) = xloc(1) / A(KPLUS1,1)
	    else
               DO J = N, 2, -1
               l = max( 1, J - K )
               xloc(l:j-1)=xloc(l:j-1)-xloc(j)*A(kplus1-j+l:k,j)
	       ENDDO
	    endif
         ELSE
            IF( NOUNIT ) then
               DO J = 1, N-1
               xloc(J) = xloc(J) / A(1,J)
               l = min( N, J + K )
               xloc(j+1:l)=xloc(j+1:l)-xloc(j)*A(2:min(n-j+1,kplus1),j)
	       ENDDO
               xloc(n) = xloc(n) / A(1,n)
	    else
               DO J = 1, N-1
               l = min( N, J + K )
               xloc(j+1:l)=xloc(j+1:l)-xloc(j)*A(2:min(n-j+1,kplus1),j)
	       ENDDO
	    endif
         END IF
      ELSE
*
*        Form  x := inv( A')*x.
*
         IF( UPPER )THEN
	    do i = 1, k
cts            a(i:i,:) = cshift(a(i:i,:),2,(k+1-i))
               a(i:i,:) = cshift(a(i:i,:),(k+1-i),2)
	    enddo
c
            IF( NOUNIT ) then
               DO J = 1, N-1
               xloc(J) = xloc(J) / A(KPLUS1,J)
               l = min( N, J + K )
               xloc(j+1:l) = xloc(j+1:l)
     &             - xloc(j)*A(k:max(1,kplus1+j-n):-1,j)
	       ENDDO
               xloc(n) = xloc(n) / A(KPLUS1,n)
	    else
               DO J = 1, N-1
               l = min( N, J + K )
               xloc(j+1:l) = xloc(j+1:l)
     &             - xloc(j)*A(k:max(1,kplus1+j-n):-1,j)
	       ENDDO
	    endif
c
	    do i = 1, k
cts            a(i:i,:) = cshift(a(i:i,:),2,-(k+1-i))
               a(i:i,:) = cshift(a(i:i,:),-(k+1-i),2)
	    enddo
         ELSE
	    do i = 2, k+1
cts            a(i:i,:) = cshift(a(i:i,:),2,1-i)
            a(i:i,:) = cshift(a(i:i,:),1-i,2)
	    enddo
c
            IF( NOUNIT ) then
               DO J = N, 2, -1
               xloc(J) = xloc(J) / A(1,J)
               l = max( 1, J - K )
               xloc(l:j-1)=xloc(l:j-1)-xloc(j)*A(min(kplus1,j):2:-1,j)
	       ENDDO
               xloc(1) = xloc(1) / A(1,1)
	    else
               DO J = N, 2, -1
               l = max( 1, J - K )
               xloc(l:j-1)=xloc(l:j-1)-xloc(j)*A(min(kplus1,j):2:-1,j)
	       ENDDO
	    endif
c
	    do i = 2, k+1
cts            a(i:i,:) = cshift(a(i:i,:),2,i-1)
            a(i:i,:) = cshift(a(i:i,:),i-1,2)
	    enddo
         END IF
      END IF
*
      if( incx.eq.1 )then
         x(1:n) = xloc
      else
         x(kx : kx+incx*(n-1) : incx) = xloc
      end if
*
      RETURN
*
*     End of DTBSV .
*
      END