<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Tie::Hash;

=head1 NAME

Tie::Hash, Tie::StdHash - base class definitions for tied hashes

=head1 SYNOPSIS

    package NewHash;
    require Tie::Hash;
    
    @ISA = (Tie::Hash);
    
    sub DELETE { ... }		# Provides needed method
    sub CLEAR { ... }		# Overrides inherited method
    
    
    package NewStdHash;
    require Tie::Hash;
    
    @ISA = (Tie::StdHash);
    
    # All methods provided by default, define only those needing overrides
    sub DELETE { ... }
    
    
    package main;
    
    tie %new_hash, 'NewHash';
    tie %new_std_hash, 'NewStdHash';

=head1 DESCRIPTION

This module provides some skeletal methods for hash-tying classes. See
L&lt;perltie&gt; for a list of the functions required in order to tie a hash
to a package. The basic B&lt;Tie::Hash&gt; package provides a C&lt;new&gt; method, as well
as methods C&lt;TIEHASH&gt;, C&lt;EXISTS&gt; and C&lt;CLEAR&gt;. The B&lt;Tie::StdHash&gt; package
provides most methods required for hashes in L&lt;perltie&gt;. It inherits from
B&lt;Tie::Hash&gt;, and causes tied hashes to behave exactly like standard hashes,
allowing for selective overloading of methods. The C&lt;new&gt; method is provided
as grandfathering in the case a class forgets to include a C&lt;TIEHASH&gt; method.

For developers wishing to write their own tied hashes, the required methods
are briefly defined below. See the L&lt;perltie&gt; section for more detailed
descriptive, as well as example code:

=over

=item TIEHASH classname, LIST

The method invoked by the command C&lt;tie %hash, classname&gt;. Associates a new
hash instance with the specified class. C&lt;LIST&gt; would represent additional
arguments (along the lines of L&lt;AnyDBM_File&gt; and compatriots) needed to
complete the association.

=item STORE this, key, value

Store datum I&lt;value&gt; into I&lt;key&gt; for the tied hash I&lt;this&gt;.

=item FETCH this, key

Retrieve the datum in I&lt;key&gt; for the tied hash I&lt;this&gt;.

=item FIRSTKEY this

Return the (key, value) pair for the first key in the hash.

=item NEXTKEY this, lastkey

Return the next key for the hash.

=item EXISTS this, key

Verify that I&lt;key&gt; exists with the tied hash I&lt;this&gt;.

The B&lt;Tie::Hash&gt; implementation is a stub that simply croaks.

=item DELETE this, key

Delete the key I&lt;key&gt; from the tied hash I&lt;this&gt;.

=item CLEAR this

Clear all values from the tied hash I&lt;this&gt;.

=back

=head1 CAVEATS

The L&lt;perltie&gt; documentation includes a method called C&lt;DESTROY&gt; as
a necessary method for tied hashes. Neither B&lt;Tie::Hash&gt; nor B&lt;Tie::StdHash&gt;
define a default for this method. This is a standard for class packages,
but may be omitted in favor of a simple default.

=head1 MORE INFORMATION

The packages relating to various DBM-related implementations (F&lt;DB_File&gt;,
F&lt;NDBM_File&gt;, etc.) show examples of general tied hashes, as does the
L&lt;Config&gt; module. While these do not utilize B&lt;Tie::Hash&gt;, they serve as
good working examples.

=cut

use Carp;
use warnings::register;

sub new {
    my $pkg = shift;
    $pkg-&gt;TIEHASH(@_);
}

# Grandfather "new"

sub TIEHASH {
    my $pkg = shift;
    if (defined &amp;{"${pkg}::new"}) {
	warnings::warnif("WARNING: calling ${pkg}-&gt;new since ${pkg}-&gt;TIEHASH is missing");
	$pkg-&gt;new(@_);
    }
    else {
	croak "$pkg doesn't define a TIEHASH method";
    }
}

sub EXISTS {
    my $pkg = ref $_[0];
    croak "$pkg doesn't define an EXISTS method";
}

sub CLEAR {
    my $self = shift;
    my $key = $self-&gt;FIRSTKEY(@_);
    my @keys;

    while (defined $key) {
	push @keys, $key;
	$key = $self-&gt;NEXTKEY(@_, $key);
    }
    foreach $key (@keys) {
	$self-&gt;DELETE(@_, $key);
    }
}

# The Tie::StdHash package implements standard perl hash behaviour.
# It exists to act as a base class for classes which only wish to
# alter some parts of their behaviour.

package Tie::StdHash;
@ISA = qw(Tie::Hash);

sub TIEHASH  { bless {}, $_[0] }
sub STORE    { $_[0]-&gt;{$_[1]} = $_[2] }
sub FETCH    { $_[0]-&gt;{$_[1]} }
sub FIRSTKEY { my $a = scalar keys %{$_[0]}; each %{$_[0]} }
sub NEXTKEY  { each %{$_[0]} }
sub EXISTS   { exists $_[0]-&gt;{$_[1]} }
sub DELETE   { delete $_[0]-&gt;{$_[1]} }
sub CLEAR    { %{$_[0]} = () }

1;
</pre></body></html>