![[Unicode]](http://www.unicode.org/webscripts/logo60s2.gif){kind=small}
Unicode
Character Database| Unicode
Character Database |
| Revision | 4.0.0 |
| Authors | Asmus Freytag |
| Date | 2003-02-21 |
| This Version | http://www.unicode.org/Public/4.0-Update/NamesList-4.0.0.html |
| Previous Version | http://www.unicode.org/Public/3.2-Update/NamesList-3.2.0.html |
| Latest Version | http://www.unicode.org/Public/UNIDATA/NamesList.html |
This file describes the format and contents of NamesList.txt
The file and the files described herein are part of the Unicode Character Database (UCD) and are governed by the UCD Terms of Use stated at the end.
The Unicode name list file NamesList.txt (also NamesList.lst) is a plain text file used to drive the layout of the character code charts in the Unicode Standard. The information in this file is a combination of several fields from the UnicodeData.txt and Blocks.txt files, together with additional annotations for many characters.
This document describes the syntax rules for the file format, but also gives brief information on how each construct is rendered when laid out for the book. Some of the syntax elements were used in preparation of the drafts of the book and may not be present in the final, released form of the NamesList.txt file.
The same input file can be used to do the draft preparation for ISO/IEC 10646 (referred below as ISO-style). This necessitates the presence of some information in the name list file that is not needed (and in fact removed during parsing) for the Unicode code charts.
With access to the layout program (unibook.exe) it is a simple matter of creating name lists for the purpose of formatting working drafts containing proposed characters.
The content of the NamesList.txt file is optimized for code chart creation. Some information that can be inferred by the reader from context has been suppressed to make the code charts more readable.
The *.lst files are plain text files which in their most simple form look like this
@@<tab>0020<tab>BASIC LATIN<tab>007F
; this is a file comment (ignored)
0020<tab>SPACE
0021<tab>EXCLAMATION MARK
0022<tab>QUOTATION MARK
. . .
007F<tab>DELETE
The semicolon (as first character), @ and <tab> characters are used by the file syntax and must be provided as shown. Hexadecimal digits must be in UPPER CASE. A double @@ introduces a block header, with the title, and start and ending code of the block provided as shown.
For an ISO-style, minimal name list, only the NAME_LINE and BLOCKHEADER and their constituent syntax elements are needed.
The full syntax with all the options is provided in the following sections.
This section gives defines the overall file structure
NAMELIST: TITLE_PAGE* BLOCK* TITLE_PAGE: TITLE | TITLE_PAGE SUBTITLE | TITLE_PAGE SUBHEADER | TITLE_PAGE IGNORED_LINE | TITLE_PAGE EMPTY_LINE | TITLE_PAGE COMMENT_LINE | TITLE_PAGE NOTICE_LINE | TITLE_PAGE PAGEBREAK BLOCK: BLOCKHEADER | BLOCK CHAR_ENTRY | BLOCK SUBHEADER | BLOCK NOTICE_LINE | BLOCK EMPTY_LINE | BLOCK IGNORED_LINE | BLOCK PAGEBREAK CHAR_ENTRY: NAME_LINE | RESERVED_LINE | CHAR_ENTRY ALIAS_LINE | CHAR_ENTRY COMMENT_LINE | CHAR_ENTRY CROSS_REF | CHAR_ENTRY DECOMPOSITION | CHAR_ENTRY COMPAT_MAPPING | CHAR_ENTRY IGNORED_LINE | CHAR_ENTRY EMPTY_LINE | CHAR_ENTRY NOTICE
In other words:
Neither TITLE nor SUBTITLE may occur after the first BLOCKHEADER.
Only TITLE, SUBTITLE, SUBHEADER, PAGEBREAK, COMMENT_LINE, and IGNORED_LINE may occur before the first BLOCKHEADER.
Directly following either a NAME_LINE or a RESERVED_LINE an uninterrupted sequence of the following lines may occur (in any order and repeated as often as needed): ALIAS_LINE, CROSS_REF, DECOMPOSITION, COMPAT_MAPPING, NOTICE_LINE, EMPTY_LINE and IGNORED_LINE.
Except for EMPTY_LINE, NOTICE_LINE and IGNORED_LINE, none of these lines may occur in any other place.
Note: A NOTICE_LINE displays differently depending on whether it follows a header or title or is part of a CHAR_ENTRY.
This section provides the details of the syntax for the individual elements.
ELEMENT SYNTAX // How rendered NAME_LINE: CHAR <tab> NAME LF // the CHAR and the corresponding image are echoed, // followed by the name as given in LINE CHAR TAB "<" LCNAME ">" LF // control and non-characters use this form of // lower case, bracketed pseudo character name
CHAR TAB NAME COMMENT LF
// Names may have a comment, which is stripped off
// unless the file is parsed for an ISO style list
RESERVED_LINE: CHAR TAB <reserved>
// the CHAR is echoed followed by an icon for the
// reserved character and a fixed string e.g. <reserved>
COMMMENT_LINE: <tab> "*" SP EXPAND_LINE
// * is replaced by BULLET, output line as comment
<tab> EXPAND_LINE
// output line as comment
ALIAS_LINE: <tab> "=" SP LINE
// replace = by itself, output line as alias
CROSS_REF: <tab> "X" SP EXPAND_LINE
// X is replaced by a right arrow
<tab> "X" SP "(" LCNAME SP "-" SP CHAR ")"
// X is replaced by a right arrow
// the "(", "-", ")" are removed, the
// order of CHAR and STRING is reversed
// i.e. both inputs result in the same output
FILE_COMMENT: ";" LINE
IGNORED_LINE: <tab> ";" EXPAND_LINE
EMPTY_LINE: LF
// empty and ignored lines as well as
// file comments are ignored
DECOMPOSITION: <tab> ":" EXPAND_LINE
// replace ':' by EQUIV, expand line into
// decomposition
COMPAT_MAPPING: <tab> "#" SP EXPAND_LINE
// replace '#' by APPROX, output line as mapping
NOTICE_LINE: "@+" <tab> LINE
// skip '@+', output text as notice
"@+" <tab> * SP LINE
// skip '@+', output text as notice
// "*" expands to a bullet character
// Notices following a character code apply to the
// character and are indented. Notices not following
// a character code apply to the page/block/column
// and are italicized, but not indented
SUBTITLE: "@@@+" <tab> LINE
// skip "@@@+", output text as subtitle
SUBHEADER: "@" <tab> LINE
// skip '@', output line as text as column header
BLOCKHEADER: "@@" <tab> BLOCKSTART <tab> BLOCKNAME <tab> BLOCKEND
// skip "@@", cause a page break and optional
// blank page, then output one or more charts
// followed by the list of character names.
// use BLOCKSTART and BLOCKEND to define the
// characters belonging to a block
// use blockname in page and table headers
BLOCKNAME: LABEL
LABEL SP "(" LABEL ")"
// if an alternate label is present it replaces
// the blockname when an ISO-style namelist is
// laid out; it is ignored in the Unicode charts
BLOCKSTART: CHAR // first character position in block
BLOCKEND: CHAR // last character position in block
PAGE_BREAK: "@@" // insert a column break
TITLE: "@@@" <tab> LINE
// skip "@@@", output line as text
// Title is used in page headers
EXPAND_LINE: {CHAR | STRING}+ LF
// all instances of CHAR *) are replaced by
// CHAR NBSP x NBSP where x is the single Unicode
// character corresponding to char
// If character is combining, it is replaced with
// CHAR NBSP <circ> x NBSP where <circ> is the
// dotted circle
Notes:
The following are the primitives and terminals for the NamesList syntax.
LINE: STRING LF
COMMENT: "(" LABEL ")"
"(" LABEl ")" SP "*"
"*"
BLOCKNAME: <sequence of Latin-1 characters, except "(" and ")">
NAME: <sequence of uppercase ASCII letters, digits and hyphen>
LCNAME: <sequence of lowercase ASCII letters, digits and hyphen>
STRING: <sequence of Latin-1 characters, except space and controls>
LABEL: <sequence of Latin-1 characters, except space, controls, "(" or ")">
CHAR: X X X X
| X X X X X
| X X X X X X
X: "0"|"1"|"2"|"3"|"4"|"5"|"6"|"7"|"8"|"9"|"A"|"B"|"C"|"D"|"E"|"F"
<tab>: <sequence of one or more ASCII tab characters 0x09>
SP: <ASCII 0x20>
LF: <any sequence of ASCII 0x0A and 0x0D>
Notes:
Version 4.0.0
Fix syntax to better reflect restrictions on characters
in character and block names.
Better document treatment of comments in block names, plus
French name rules.
Version 3.2.0
Fixed several broken links, added a left margin,
changed version numbering.
Version 3.1.0 (2)
Use of 4-6 digit hex notation is now supported.
The Unicode Character Database is provided as is by Unicode, Inc. No claims are made as to fitness for any particular purpose. No warranties of any kind are expressed or implied. The recipient agrees to determine applicability of information provided. If this file has been purchased on magnetic or optical media from Unicode, Inc., the sole remedy for any claim will be exchange of defective media within 90 days of receipt.
This disclaimer is applicable for all other data files accompanying the Unicode Character Database, some of which have been compiled by the Unicode Consortium, and some of which have been supplied by other sources.
Recipient is granted the right to make copies in any form for internal distribution and to freely use the information supplied in the creation of products supporting the UnicodeTM Standard. The files in the Unicode Character Database can be redistributed to third parties or other organizations (whether for profit or not) as long as this notice and the disclaimer notice are retained. Information can be extracted from these files and used in documentation or programs, as long as there is an accompanying notice indicating the source.
 |