<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;"># Parse an L&lt;&gt; formatting code in POD text.
#
# This module implements parsing of the text of an L&lt;&gt; formatting code as
# defined in perlpodspec.  It should be suitable for any POD formatter.  It
# exports only one function, parselink(), which returns the five-item parse
# defined in perlpodspec.
#
# SPDX-License-Identifier: GPL-1.0-or-later OR Artistic-1.0-Perl

##############################################################################
# Modules and declarations
##############################################################################

package Pod::ParseLink;

use 5.010;
use strict;
use warnings;

use Exporter;

our @ISA = qw(Exporter);
our @EXPORT = qw(parselink);
our $VERSION = '5.01_02';
$VERSION =~ tr/_//d;

##############################################################################
# Implementation
##############################################################################

# Parse the name and section portion of a link into a name and section.
sub _parse_section {
    my ($link) = @_;
    $link =~ s/^\s+//;
    $link =~ s/\s+$//;

    # If the whole link is enclosed in quotes, interpret it all as a section
    # even if it contains a slash.
    return (undef, $1) if ($link =~ /^"\s*(.*?)\s*"$/);

    # Split into page and section on slash, and then clean up quoting in the
    # section.  If there is no section and the name contains spaces, also
    # guess that it's an old section link.
    my ($page, $section) = split (/\s*\/\s*/, $link, 2);
    $section =~ s/^"\s*(.*?)\s*"$/$1/ if $section;
    if ($page &amp;&amp; $page =~ / / &amp;&amp; !defined ($section)) {
        $section = $page;
        $page = undef;
    } else {
        $page = undef unless $page;
        $section = undef unless $section;
    }
    return ($page, $section);
}

# Infer link text from the page and section.
sub _infer_text {
    my ($page, $section) = @_;
    my $inferred;
    if ($page &amp;&amp; !$section) {
        $inferred = $page;
    } elsif (!$page &amp;&amp; $section) {
        $inferred = '"' . $section . '"';
    } elsif ($page &amp;&amp; $section) {
        $inferred = '"' . $section . '" in ' . $page;
    }
    return $inferred;
}

# Given the contents of an L&lt;&gt; formatting code, parse it into the link text,
# the possibly inferred link text, the name or URL, the section, and the type
# of link (pod, man, or url).
sub parselink {
    my ($link) = @_;
    $link =~ s/\s+/ /g;
    my $text;
    if ($link =~ /\|/) {
        ($text, $link) = split (/\|/, $link, 2);
    }
    if ($link =~ /\A\w+:[^:\s]\S*\Z/) {
        my $inferred;
        if (defined ($text) &amp;&amp; length ($text) &gt; 0) {
            return ($text, $text, $link, undef, 'url');
        } else {
            return ($text, $link, $link, undef, 'url');
        }
    } else {
        my ($name, $section) = _parse_section ($link);
        my $inferred;
        if (defined ($text) &amp;&amp; length ($text) &gt; 0) {
            $inferred = $text;
        } else {
            $inferred = _infer_text ($name, $section);
        }
        my $type = ($name &amp;&amp; $name =~ /\(\S*\)/) ? 'man' : 'pod';
        return ($text, $inferred, $name, $section, $type);
    }
}

##############################################################################
# Module return value and documentation
##############################################################################

# Ensure we evaluate to true.
1;
__END__

=for stopwords
markup Allbery URL

=head1 NAME

Pod::ParseLink - Parse an LE&lt;lt&gt;E&lt;gt&gt; formatting code in POD text

=head1 SYNOPSIS

    use Pod::ParseLink;
    my $link = get_link();
    my ($text, $inferred, $name, $section, $type) = parselink($link);

=head1 DESCRIPTION

This module only provides a single function, parselink(), which takes the
text of an LE&lt;lt&gt;E&lt;gt&gt; formatting code and parses it.  It returns the
anchor text for the link (if any was given), the anchor text possibly
inferred from the name and section, the name or URL, the section if any,
and the type of link.  The type will be one of C&lt;url&gt;, C&lt;pod&gt;, or C&lt;man&gt;,
indicating a URL, a link to a POD page, or a link to a Unix manual page.

Parsing is implemented per L&lt;perlpodspec&gt;.  For backward compatibility,
links where there is no section and name contains spaces, or links where the
entirety of the link (except for the anchor text if given) is enclosed in
double-quotes are interpreted as links to a section (LE&lt;lt&gt;/sectionE&lt;gt&gt;).

The inferred anchor text is implemented per L&lt;perlpodspec&gt;:

    L&lt;name&gt;         =&gt;  L&lt;name|name&gt;
    L&lt;/section&gt;     =&gt;  L&lt;"section"|/section&gt;
    L&lt;name/section&gt; =&gt;  L&lt;"section" in name|name/section&gt;

The name may contain embedded EE&lt;lt&gt;E&lt;gt&gt; and ZE&lt;lt&gt;E&lt;gt&gt; formatting codes,
and the section, anchor text, and inferred anchor text may contain any
formatting codes.  Any double quotes around the section are removed as part
of the parsing, as is any leading or trailing whitespace.

If the text of the LE&lt;lt&gt;E&lt;gt&gt; escape is entirely enclosed in double
quotes, it's interpreted as a link to a section for backward
compatibility.

No attempt is made to resolve formatting codes.  This must be done after
calling parselink() (since EE&lt;lt&gt;E&lt;gt&gt; formatting codes can be used to
escape characters that would otherwise be significant to the parser and
resolving them before parsing would result in an incorrect parse of a
formatting code like:

    L&lt;verticalE&lt;verbar&gt;barE&lt;sol&gt;slash&gt;

which should be interpreted as a link to the C&lt;vertical|bar/slash&gt; POD page
and not as a link to the C&lt;slash&gt; section of the C&lt;bar&gt; POD page with an
anchor text of C&lt;vertical&gt;.  Note that not only the anchor text will need to
have formatting codes expanded, but so will the target of the link (to deal
with EE&lt;lt&gt;E&lt;gt&gt; and ZE&lt;lt&gt;E&lt;gt&gt; formatting codes), and special handling of
the section may be necessary depending on whether the translator wants to
consider markup in sections to be significant when resolving links.  See
L&lt;perlpodspec&gt; for more information.

=head1 AUTHOR

Russ Allbery &lt;rra@cpan.org&gt;

=head1 COPYRIGHT AND LICENSE

Copyright 2001, 2008, 2009, 2014, 2018-2019, 2022 Russ Allbery &lt;rra@cpan.org&gt;

This program is free software; you may redistribute it and/or modify it
under the same terms as Perl itself.

=head1 SEE ALSO

L&lt;Pod::Parser&gt;

The current version of this module is always available from its web site at
L&lt;https://www.eyrie.org/~eagle/software/podlators/&gt;.

=cut

# Local Variables:
# copyright-at-end-flag: t
# End:
</pre></body></html>