<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#############################################################################
# Pod/ParseUtils.pm -- helpers for POD parsing and conversion
#
# Copyright (C) 1999-2000 by Marek Rouchal. All rights reserved.
# This file is part of "PodParser". PodParser is free software;
# you can redistribute it and/or modify it under the same terms
# as Perl itself.
#############################################################################

package Pod::ParseUtils;

use vars qw($VERSION);
$VERSION = 0.22;   ## Current version of this package
require  5.005;    ## requires this Perl version or later

=head1 NAME

Pod::ParseUtils - helpers for POD parsing and conversion

=head1 SYNOPSIS

  use Pod::ParseUtils;

  my $list = new Pod::List;
  my $link = Pod::Hyperlink-&gt;new('Pod::Parser');

=head1 DESCRIPTION

B&lt;Pod::ParseUtils&gt; contains a few object-oriented helper packages for
POD parsing and processing (i.e. in POD formatters and translators).

=cut

#-----------------------------------------------------------------------------
# Pod::List
#
# class to hold POD list info (=over, =item, =back)
#-----------------------------------------------------------------------------

package Pod::List;

use Carp;

=head2 Pod::List

B&lt;Pod::List&gt; can be used to hold information about POD lists
(written as =over ... =item ... =back) for further processing.
The following methods are available:

=over 4

=item Pod::List-E&lt;gt&gt;new()

Create a new list object. Properties may be specified through a hash
reference like this:

  my $list = Pod::List-&gt;new({ -start =&gt; $., -indent =&gt; 4 });

See the individual methods/properties for details.

=cut

sub new {
    my $this = shift;
    my $class = ref($this) || $this;
    my %params = @_;
    my $self = {%params};
    bless $self, $class;
    $self-&gt;initialize();
    return $self;
}

sub initialize {
    my $self = shift;
    $self-&gt;{-file} ||= 'unknown';
    $self-&gt;{-start} ||= 'unknown';
    $self-&gt;{-indent} ||= 4; # perlpod: "should be the default"
    $self-&gt;{_items} = [];
    $self-&gt;{-type} ||= '';
}

=item $list-E&lt;gt&gt;file()

Without argument, retrieves the file name the list is in. This must
have been set before by either specifying B&lt;-file&gt; in the B&lt;new()&gt;
method or by calling the B&lt;file()&gt; method with a scalar argument.

=cut

# The POD file name the list appears in
sub file {
   return (@_ &gt; 1) ? ($_[0]-&gt;{-file} = $_[1]) : $_[0]-&gt;{-file};
}

=item $list-E&lt;gt&gt;start()

Without argument, retrieves the line number where the list started.
This must have been set before by either specifying B&lt;-start&gt; in the
B&lt;new()&gt; method or by calling the B&lt;start()&gt; method with a scalar
argument.

=cut

# The line in the file the node appears
sub start {
   return (@_ &gt; 1) ? ($_[0]-&gt;{-start} = $_[1]) : $_[0]-&gt;{-start};
}

=item $list-E&lt;gt&gt;indent()

Without argument, retrieves the indent level of the list as specified
in C&lt;=over n&gt;. This must have been set before by either specifying
B&lt;-indent&gt; in the B&lt;new()&gt; method or by calling the B&lt;indent()&gt; method
with a scalar argument.

=cut

# indent level
sub indent {
   return (@_ &gt; 1) ? ($_[0]-&gt;{-indent} = $_[1]) : $_[0]-&gt;{-indent};
}

=item $list-E&lt;gt&gt;type()

Without argument, retrieves the list type, which can be an arbitrary value,
e.g. C&lt;OL&gt;, C&lt;UL&gt;, ... when thinking the HTML way.
This must have been set before by either specifying
B&lt;-type&gt; in the B&lt;new()&gt; method or by calling the B&lt;type()&gt; method
with a scalar argument.

=cut

# The type of the list (UL, OL, ...)
sub type {
   return (@_ &gt; 1) ? ($_[0]-&gt;{-type} = $_[1]) : $_[0]-&gt;{-type};
}

=item $list-E&lt;gt&gt;rx()

Without argument, retrieves a regular expression for simplifying the 
individual item strings once the list type has been determined. Usage:
E.g. when converting to HTML, one might strip the leading number in
an ordered list as C&lt;E&lt;lt&gt;OLE&lt;gt&gt;&gt; already prints numbers itself.
This must have been set before by either specifying
B&lt;-rx&gt; in the B&lt;new()&gt; method or by calling the B&lt;rx()&gt; method
with a scalar argument.

=cut

# The regular expression to simplify the items
sub rx {
   return (@_ &gt; 1) ? ($_[0]-&gt;{-rx} = $_[1]) : $_[0]-&gt;{-rx};
}

=item $list-E&lt;gt&gt;item()

Without argument, retrieves the array of the items in this list.
The items may be represented by any scalar.
If an argument has been given, it is pushed on the list of items.

=cut

# The individual =items of this list
sub item {
    my ($self,$item) = @_;
    if(defined $item) {
        push(@{$self-&gt;{_items}}, $item);
        return $item;
    }
    else {
        return @{$self-&gt;{_items}};
    }
}

=item $list-E&lt;gt&gt;parent()

Without argument, retrieves information about the parent holding this
list, which is represented as an arbitrary scalar.
This must have been set before by either specifying
B&lt;-parent&gt; in the B&lt;new()&gt; method or by calling the B&lt;parent()&gt; method
with a scalar argument.

=cut

# possibility for parsers/translators to store information about the
# lists's parent object
sub parent {
   return (@_ &gt; 1) ? ($_[0]-&gt;{-parent} = $_[1]) : $_[0]-&gt;{-parent};
}

=item $list-E&lt;gt&gt;tag()

Without argument, retrieves information about the list tag, which can be
any scalar.
This must have been set before by either specifying
B&lt;-tag&gt; in the B&lt;new()&gt; method or by calling the B&lt;tag()&gt; method
with a scalar argument.

=back

=cut

# possibility for parsers/translators to store information about the
# list's object
sub tag {
   return (@_ &gt; 1) ? ($_[0]-&gt;{-tag} = $_[1]) : $_[0]-&gt;{-tag};
}

#-----------------------------------------------------------------------------
# Pod::Hyperlink
#
# class to manipulate POD hyperlinks (L&lt;&gt;)
#-----------------------------------------------------------------------------

package Pod::Hyperlink;

=head2 Pod::Hyperlink

B&lt;Pod::Hyperlink&gt; is a class for manipulation of POD hyperlinks. Usage:

  my $link = Pod::Hyperlink-&gt;new('alternative text|page/"section in page"');

The B&lt;Pod::Hyperlink&gt; class is mainly designed to parse the contents of the
C&lt;LE&lt;lt&gt;...E&lt;gt&gt;&gt; sequence, providing a simple interface for accessing the
different parts of a POD hyperlink for further processing. It can also be
used to construct hyperlinks.

=over 4

=item Pod::Hyperlink-E&lt;gt&gt;new()

The B&lt;new()&gt; method can either be passed a set of key/value pairs or a single
scalar value, namely the contents of a C&lt;LE&lt;lt&gt;...E&lt;gt&gt;&gt; sequence. An object
of the class C&lt;Pod::Hyperlink&gt; is returned. The value C&lt;undef&gt; indicates a
failure, the error message is stored in C&lt;$@&gt;.

=cut

use Carp;

sub new {
    my $this = shift;
    my $class = ref($this) || $this;
    my $self = +{};
    bless $self, $class;
    $self-&gt;initialize();
    if(defined $_[0]) {
        if(ref($_[0])) {
            # called with a list of parameters
            %$self = %{$_[0]};
            $self-&gt;_construct_text();
        }
        else {
            # called with L&lt;&gt; contents
            return undef unless($self-&gt;parse($_[0]));
        }
    }
    return $self;
}

sub initialize {
    my $self = shift;
    $self-&gt;{-line} ||= 'undef';
    $self-&gt;{-file} ||= 'undef';
    $self-&gt;{-page} ||= '';
    $self-&gt;{-node} ||= '';
    $self-&gt;{-alttext} ||= '';
    $self-&gt;{-type} ||= 'undef';
    $self-&gt;{_warnings} = [];
}

=item $link-E&lt;gt&gt;parse($string)

This method can be used to (re)parse a (new) hyperlink, i.e. the contents
of a C&lt;LE&lt;lt&gt;...E&lt;gt&gt;&gt; sequence. The result is stored in the current object.
Warnings are stored in the B&lt;warnings&gt; property.
E.g. sections like C&lt;LE&lt;lt&gt;open(2)E&lt;gt&gt;&gt; are deprected, as they do not point
to Perl documents. C&lt;LE&lt;lt&gt;DBI::foo(3p)E&lt;gt&gt;&gt; is wrong as well, the manpage
section can simply be dropped.

=cut

sub parse {
    my $self = shift;
    local($_) = $_[0];
    # syntax check the link and extract destination
    my ($alttext,$page,$node,$type) = (undef,'','','');

    $self-&gt;{_warnings} = [];

    # collapse newlines with whitespace
    s/\s*\n+\s*/ /g;

    # strip leading/trailing whitespace
    if(s/^[\s\n]+//) {
        $self-&gt;warning("ignoring leading whitespace in link");
    }
    if(s/[\s\n]+$//) {
        $self-&gt;warning("ignoring trailing whitespace in link");
    }
    unless(length($_)) {
        _invalid_link("empty link");
        return undef;
    }

    ## Check for different possibilities. This is tedious and error-prone
    # we match all possibilities (alttext, page, section/item)
    #warn "DEBUG: link=$_\n";

    # only page
    # problem: a lot of people use (), or (1) or the like to indicate
    # man page sections. But this collides with L&lt;func()&gt; that is supposed
    # to point to an internal funtion...
    my $page_rx = '[\w.]+(?:::[\w.]+)*(?:[(](?:\d\w*|)[)]|)';
    # page name only
    if(m!^($page_rx)$!o) {
        $page = $1;
        $type = 'page';
    }
    # alttext, page and "section"
    elsif(m!^(.*?)\s*[|]\s*($page_rx)\s*/\s*"(.+)"$!o) {
        ($alttext, $page, $node) = ($1, $2, $3);
        $type = 'section';
    }
    # alttext and page
    elsif(m!^(.*?)\s*[|]\s*($page_rx)$!o) {
        ($alttext, $page) = ($1, $2);
        $type = 'page';
    }
    # alttext and "section"
    elsif(m!^(.*?)\s*[|]\s*(?:/\s*|)"(.+)"$!) {
        ($alttext, $node) = ($1,$2);
        $type = 'section';
    }
    # page and "section"
    elsif(m!^($page_rx)\s*/\s*"(.+)"$!o) {
        ($page, $node) = ($1, $2);
        $type = 'section';
    }
    # page and item
    elsif(m!^($page_rx)\s*/\s*(.+)$!o) {
        ($page, $node) = ($1, $2);
        $type = 'item';
    }
    # only "section"
    elsif(m!^/?"(.+)"$!) {
        $node = $1;
        $type = 'section';
    }
    # only item
    elsif(m!^\s*/(.+)$!) {
        $node = $1;
        $type = 'item';
    }
    # non-standard: Hyperlink
    elsif(m!^((?:http|ftp|mailto|news):.+)$!i) {
        $node = $1;
        $type = 'hyperlink';
    }
    # alttext, page and item
    elsif(m!^(.*?)\s*[|]\s*($page_rx)\s*/\s*(.+)$!o) {
        ($alttext, $page, $node) = ($1, $2, $3);
        $type = 'item';
    }
    # alttext and item
    elsif(m!^(.*?)\s*[|]\s*/(.+)$!) {
        ($alttext, $node) = ($1,$2);
    }
    # nonstandard: alttext and hyperlink
    elsif(m!^(.*?)\s*[|]\s*((?:http|ftp|mailto|news):.+)$!) {
        ($alttext, $node) = ($1,$2);
        $type = 'hyperlink';
    }
    # must be an item or a "malformed" section (without "")
    else {
        $node = $_;
        $type = 'item';
    }
    # collapse whitespace in nodes
    $node =~ s/\s+/ /gs;

    # empty alternative text expands to node name
    if(defined $alttext) {
        if(!length($alttext)) {
          $alttext = $node | $page;
        }
    }
    else {
        $alttext = '';
    }

    if($page =~ /[(]\w*[)]$/) {
        $self-&gt;warning("(section) in '$page' deprecated");
    }
    if($node =~ m:[|/]:) {
        $self-&gt;warning("node '$node' contains non-escaped | or /");
    }
    if($alttext =~ m:[|/]:) {
        $self-&gt;warning("alternative text '$node' contains non-escaped | or /");
    }
    $self-&gt;{-page} = $page;
    $self-&gt;{-node} = $node;
    $self-&gt;{-alttext} = $alttext;
    #warn "DEBUG: page=$page section=$section item=$item alttext=$alttext\n";
    $self-&gt;{-type} = $type;
    $self-&gt;_construct_text();
    1;
}

sub _construct_text {
    my $self = shift;
    my $alttext = $self-&gt;alttext();
    my $type = $self-&gt;type();
    my $section = $self-&gt;node();
    my $page = $self-&gt;page();
    my $page_ext = '';
    $page =~ s/([(]\w*[)])$// &amp;&amp; ($page_ext = $1);
    if($alttext) {
        $self-&gt;{_text} = $alttext;
    }
    elsif($type eq 'hyperlink') {
        $self-&gt;{_text} = $section;
    }
    else {
        $self-&gt;{_text} = (!$section ? '' : 
            $type eq 'item' ? "the $section entry" :
                "the section on $section" ) .
            ($page ? ($section ? ' in ':'') . "the $page$page_ext manpage" :
                ' elsewhere in this document');
    }
    # for being marked up later
    # use the non-standard markers P&lt;&gt; and Q&lt;&gt;, so that the resulting
    # text can be parsed by the translators. It's their job to put
    # the correct hypertext around the linktext
    if($alttext) {
        $self-&gt;{_markup} = "Q&lt;$alttext&gt;";
    }
    elsif($type eq 'hyperlink') {
        $self-&gt;{_markup} = "Q&lt;$section&gt;";
    }
    else {
        $self-&gt;{_markup} = (!$section ? '' : 
            $type eq 'item' ? "the Q&lt;$section&gt; entry" :
                "the section on Q&lt;$section&gt;" ) .
            ($page ? ($section ? ' in ':'') . "the P&lt;$page&gt;$page_ext manpage" :
                ' elsewhere in this document');
    }
}

=item $link-E&lt;gt&gt;markup($string)

Set/retrieve the textual value of the link. This string contains special
markers C&lt;PE&lt;lt&gt;E&lt;gt&gt;&gt; and C&lt;QE&lt;lt&gt;E&lt;gt&gt;&gt; that should be expanded by the
translator's interior sequence expansion engine to the
formatter-specific code to highlight/activate the hyperlink. The details
have to be implemented in the translator.

=cut

#' retrieve/set markuped text
sub markup {
    return (@_ &gt; 1) ? ($_[0]-&gt;{_markup} = $_[1]) : $_[0]-&gt;{_markup};
}

=item $link-E&lt;gt&gt;text()

This method returns the textual representation of the hyperlink as above,
but without markers (read only). Depending on the link type this is one of
the following alternatives (the + and * denote the portions of the text
that are marked up):

  the +perl+ manpage
  the *$|* entry in the +perlvar+ manpage
  the section on *OPTIONS* in the +perldoc+ manpage
  the section on *DESCRIPTION* elsewhere in this document

=cut

# The complete link's text
sub text {
    $_[0]-&gt;{_text};
}

=item $link-E&lt;gt&gt;warning()

After parsing, this method returns any warnings encountered during the
parsing process.

=cut

# Set/retrieve warnings
sub warning {
    my $self = shift;
    if(@_) {
        push(@{$self-&gt;{_warnings}}, @_);
        return @_;
    }
    return @{$self-&gt;{_warnings}};
}

=item $link-E&lt;gt&gt;file()

=item $link-E&lt;gt&gt;line()

Just simple slots for storing information about the line and the file
the link was encountered in. Has to be filled in manually.

=cut

# The line in the file the link appears
sub line {
    return (@_ &gt; 1) ? ($_[0]-&gt;{-line} = $_[1]) : $_[0]-&gt;{-line};
}

# The POD file name the link appears in
sub file {
    return (@_ &gt; 1) ? ($_[0]-&gt;{-file} = $_[1]) : $_[0]-&gt;{-file};
}

=item $link-E&lt;gt&gt;page()

This method sets or returns the POD page this link points to.

=cut

# The POD page the link appears on
sub page {
    if (@_ &gt; 1) {
        $_[0]-&gt;{-page} = $_[1];
        $_[0]-&gt;_construct_text();
    }
    $_[0]-&gt;{-page};
}

=item $link-E&lt;gt&gt;node()

As above, but the destination node text of the link.

=cut

# The link destination
sub node {
    if (@_ &gt; 1) {
        $_[0]-&gt;{-node} = $_[1];
        $_[0]-&gt;_construct_text();
    }
    $_[0]-&gt;{-node};
}

=item $link-E&lt;gt&gt;alttext()

Sets or returns an alternative text specified in the link.

=cut

# Potential alternative text
sub alttext {
    if (@_ &gt; 1) {
        $_[0]-&gt;{-alttext} = $_[1];
        $_[0]-&gt;_construct_text();
    }
    $_[0]-&gt;{-alttext};
}

=item $link-E&lt;gt&gt;type()

The node type, either C&lt;section&gt; or C&lt;item&gt;. As an unofficial type,
there is also C&lt;hyperlink&gt;, derived from e.g. C&lt;LE&lt;lt&gt;http://perl.comE&lt;gt&gt;&gt;

=cut

# The type: item or headn
sub type {
    return (@_ &gt; 1) ? ($_[0]-&gt;{-type} = $_[1]) : $_[0]-&gt;{-type};
}

=item $link-E&lt;gt&gt;link()

Returns the link as contents of C&lt;LE&lt;lt&gt;E&lt;gt&gt;&gt;. Reciprocal to B&lt;parse()&gt;.

=back

=cut

# The link itself
sub link {
    my $self = shift;
    my $link = $self-&gt;page() || '';
    if($self-&gt;node()) {
        my $node = $self-&gt;node();
        $text =~ s/\|/E&lt;verbar&gt;/g;
        $text =~ s:/:E&lt;sol&gt;:g;
        if($self-&gt;type() eq 'section') {
            $link .= ($link ? '/' : '') . '"' . $node . '"';
        }
        elsif($self-&gt;type() eq 'hyperlink') {
            $link = $self-&gt;node();
        }
        else { # item
            $link .= '/' . $node;
        }
    }
    if($self-&gt;alttext()) {
        my $text = $self-&gt;alttext();
        $text =~ s/\|/E&lt;verbar&gt;/g;
        $text =~ s:/:E&lt;sol&gt;:g;
        $link = "$text|$link";
    }
    $link;
}

sub _invalid_link {
    my ($msg) = @_;
    # this sets @_
    #eval { die "$msg\n" };
    #chomp $@;
    $@ = $msg; # this seems to work, too!
    undef;
}

#-----------------------------------------------------------------------------
# Pod::Cache
#
# class to hold POD page details
#-----------------------------------------------------------------------------

package Pod::Cache;

=head2 Pod::Cache

B&lt;Pod::Cache&gt; holds information about a set of POD documents,
especially the nodes for hyperlinks.
The following methods are available:

=over 4

=item Pod::Cache-E&lt;gt&gt;new()

Create a new cache object. This object can hold an arbitrary number of
POD documents of class Pod::Cache::Item.

=cut

sub new {
    my $this = shift;
    my $class = ref($this) || $this;
    my $self = [];
    bless $self, $class;
    return $self;
}

=item $cache-E&lt;gt&gt;item()

Add a new item to the cache. Without arguments, this method returns a
list of all cache elements.

=cut

sub item {
    my ($self,%param) = @_;
    if(%param) {
        my $item = Pod::Cache::Item-&gt;new(%param);
        push(@$self, $item);
        return $item;
    }
    else {
        return @{$self};
    }
}

=item $cache-E&lt;gt&gt;find_page($name)

Look for a POD document named C&lt;$name&gt; in the cache. Returns the
reference to the corresponding Pod::Cache::Item object or undef if
not found.

=back

=cut

sub find_page {
    my ($self,$page) = @_;
    foreach(@$self) {
        if($_-&gt;page() eq $page) {
            return $_;
        }
    }
    undef;
}

package Pod::Cache::Item;

=head2 Pod::Cache::Item

B&lt;Pod::Cache::Item&gt; holds information about individual POD documents,
that can be grouped in a Pod::Cache object.
It is intended to hold information about the hyperlink nodes of POD
documents.
The following methods are available:

=over 4

=item Pod::Cache::Item-E&lt;gt&gt;new()

Create a new object.

=cut

sub new {
    my $this = shift;
    my $class = ref($this) || $this;
    my %params = @_;
    my $self = {%params};
    bless $self, $class;
    $self-&gt;initialize();
    return $self;
}

sub initialize {
    my $self = shift;
    $self-&gt;{-nodes} = [] unless(defined $self-&gt;{-nodes});
}

=item $cacheitem-E&lt;gt&gt;page()

Set/retrieve the POD document name (e.g. "Pod::Parser").

=cut

# The POD page
sub page {
   return (@_ &gt; 1) ? ($_[0]-&gt;{-page} = $_[1]) : $_[0]-&gt;{-page};
}

=item $cacheitem-E&lt;gt&gt;description()

Set/retrieve the POD short description as found in the C&lt;=head1 NAME&gt;
section.

=cut

# The POD description, taken out of NAME if present
sub description {
   return (@_ &gt; 1) ? ($_[0]-&gt;{-description} = $_[1]) : $_[0]-&gt;{-description};
}

=item $cacheitem-E&lt;gt&gt;path()

Set/retrieve the POD file storage path.

=cut

# The file path
sub path {
   return (@_ &gt; 1) ? ($_[0]-&gt;{-path} = $_[1]) : $_[0]-&gt;{-path};
}

=item $cacheitem-E&lt;gt&gt;file()

Set/retrieve the POD file name.

=cut

# The POD file name
sub file {
   return (@_ &gt; 1) ? ($_[0]-&gt;{-file} = $_[1]) : $_[0]-&gt;{-file};
}

=item $cacheitem-E&lt;gt&gt;nodes()

Add a node (or a list of nodes) to the document's node list. Note that
the order is kept, i.e. start with the first node and end with the last.
If no argument is given, the current list of nodes is returned in the
same order the nodes have been added.
A node can be any scalar, but usually is a pair of node string and
unique id for the C&lt;find_node&gt; method to work correctly.

=cut

# The POD nodes
sub nodes {
    my ($self,@nodes) = @_;
    if(@nodes) {
        push(@{$self-&gt;{-nodes}}, @nodes);
        return @nodes;
    }
    else {
        return @{$self-&gt;{-nodes}};
    }
}

=item $cacheitem-E&lt;gt&gt;find_node($name)

Look for a node or index entry named C&lt;$name&gt; in the object.
Returns the unique id of the node (i.e. the second element of the array
stored in the node arry) or undef if not found.

=cut

sub find_node {
    my ($self,$node) = @_;
    my @search;
    push(@search, @{$self-&gt;{-nodes}}) if($self-&gt;{-nodes});
    push(@search, @{$self-&gt;{-idx}}) if($self-&gt;{-idx});
    foreach(@search) {
        if($_-&gt;[0] eq $node) {
            return $_-&gt;[1]; # id
        }
    }
    undef;
}

=item $cacheitem-E&lt;gt&gt;idx()

Add an index entry (or a list of them) to the document's index list. Note that
the order is kept, i.e. start with the first node and end with the last.
If no argument is given, the current list of index entries is returned in the
same order the entries have been added.
An index entry can be any scalar, but usually is a pair of string and
unique id.

=back

=cut

# The POD index entries
sub idx {
    my ($self,@idx) = @_;
    if(@idx) {
        push(@{$self-&gt;{-idx}}, @idx);
        return @idx;
    }
    else {
        return @{$self-&gt;{-idx}};
    }
}

=head1 AUTHOR

Marek Rouchal E&lt;lt&gt;marek@saftsack.fs.uni-bayreuth.deE&lt;gt&gt;, borrowing
a lot of things from L&lt;pod2man&gt; and L&lt;pod2roff&gt; as well as other POD
processing tools by Tom Christiansen, Brad Appleton and Russ Allbery.

=head1 SEE ALSO

L&lt;pod2man&gt;, L&lt;pod2roff&gt;, L&lt;Pod::Parser&gt;, L&lt;Pod::Checker&gt;,
L&lt;pod2html&gt;

=cut

1;
</pre></body></html>