<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Test2::Compare::Negatable;
use strict;
use warnings;

our $VERSION = '0.000162';

require overload;
require Test2::Util::HashBase;

sub import {
    my ($pkg, $file, $line) = caller;

    my $sub = eval &lt;&lt;"    EOT" or die $@;
package $pkg;
#line $line "$file"
sub { overload-&gt;import('!' =&gt; 'clone_negate', fallback =&gt; 1); Test2::Util::HashBase-&gt;import('negate')}
    EOT

    $sub-&gt;();

    no strict 'refs';
    *{"$pkg\::clone_negate"} = \&amp;clone_negate;
    *{"$pkg\::toggle_negate"} = \&amp;toggle_negate;
}

sub clone_negate {
    my $self = shift;
    my $clone = $self-&gt;clone;
    $clone-&gt;toggle_negate;
    return $clone;
}

sub toggle_negate {
    my $self = shift;
    $self-&gt;set_negate($self-&gt;negate ? 0 : 1);
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Test2::Compare::Negatable - Poor mans 'role' for compare objects that can be negated.

=head1 DESCRIPTION

Using this package inside an L&lt;Test2::Compare::Base&gt; subclass will overload
C&lt;!$obj&gt; and import C&lt;clone_negate()&gt; and C&lt;toggle_negate()&gt;.

=head1 WHY?

Until perl 5.18 the 'fallback' parameter to L&lt;overload&gt; would not be inherited,
so we cannot use inheritance for the behavior we actually want. This module
works around the problem by emulating the C&lt;use overload&gt; call we want for each
consumer class.

=head1 ATTRIBUTES

=over 4

=item $bool = $obj-&gt;negate

=item $obj-&gt;set_negate($bool)

=item $attr = NEGATE()

The NEGATE attribute will be added via L&lt;Test2::Util::HashBase&gt;.

=back

=head1 METHODS

=over 4

=item $clone = $obj-&gt;clone_negate()

Create a shallow copy of the object, and call C&lt;toggle_negate&gt; on it.

=item $obj-&gt;toggle_negate()

Toggle the negate attribute. If the attribute was on it will now be off, if it
was off it will now be on.

=back

=head1 SOURCE

The source code repository for Test2-Suite can be found at
F&lt;https://github.com/Test-More/Test2-Suite/&gt;.

=head1 MAINTAINERS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 AUTHORS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 COPYRIGHT

Copyright 2018 Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

See F&lt;http://dev.perl.org/licenses/&gt;

=cut
</pre></body></html>